# build hardware floating point binaries
# (tune-coretexa8.inc sets "armv7a-neon" as default)
DEFAULTTUNE ?= "armv7athf-neon"

# build for cortex a8
# (for our vexpress board we could use tune-cortexa9.inc, but
#  we wanted to stay compatible with beaglebone/cortex-a8)
require conf/machine/include/tune-cortexa8.inc

# for generating a qemu-boot.conf file
require conf/machine/include/qemu.inc
QB_SYSTEM_NAME = "qemu-system-arm"
QB_MACHINE = "-machine vexpress-a9"
QB_DEFAULT_KERNEL = "u-boot.uimg"
# for using tftpboot set QB_NETWORK_DEVICE to "-net user,tftp=tmp/deploy/images/vexpress"
QB_NETWORK_DEVICE = "-device virtio-net-device,mac=@MAC@ -net user"
QB_DEFAULT_FSTYPE = "wic"
QB_DRIVE_TYPE = "/dev/mmcblk"
QB_OPT_APPEND = "-nographic"
KERNEL_IMAGETYPE ?= "u-boot.uimg"

# machine features are used to install additional packages and can
# be set to values like:
# MACHINE_FEATURES="alsa bluetooth usbgadget screen rtc qemu-usermode"
MACHINE_FEATURES=""

# build tarballs of root filesystems
IMAGE_FSTYPES += "tar.gz"

# build ext4 images
IMAGE_FSTYPES += "ext4"

# build ext2 images
IMAGE_FSTYPES += "ext2"

# build sdcard image
IMAGE_FSTYPES += "wic wic.bmap"
WKS_FILE ?= "vexpress.wks"
do_image_wic[depends] += "qemu-boot-files:do_deploy mtools-native:do_populate_sysroot dosfstools-native:do_populate_sysroot"
# files that should be stored on the /boot partition of the sdcard
IMAGE_BOOT_FILES = "image.fit"

# build ubi images
# (the "ubi" image type requires addition hardware-specific details for
#  creating the image... what variables are needed and how they are used
#  can be seen in image_types.bbclass, in the IMAGE_CMD_ubifs function)
MKUBIFS_ARGS = "-m 1 -e 524160 -c 256"
UBINIZE_ARGS = "-m 1 -p 524288 -s 1"
UBI_VOLNAME = "rootfs"
IMAGE_FSTYPES += "ubi"

# set the default device tree for this board
# (this is a variable we created, used by the linux-basic recipe)
DTB ?= "vexpress-v2p-ca9.dtb"

# set the baud rate and device for the serial console
# (bitbake.conf adds value to a ${SERIAL_CONSOLES} list, but it is up to
#  invididual recipes to do something useful with this information
SERIAL_CONSOLE = "115200 ttyAMA0"

# use linux-basic as kernel recipe
PREFERRED_PROVIDER_virtual/kernel = "linux-basic"
# and install the kernel modules into the rootfs
MACHINE_EXTRA_RRECOMMENDS = "kernel-modules"

# use u-boot as bootloader
PREFERRED_PROVIDER_virtual/bootloader = "u-boot"
# build the make target 'u-boot-nodtb'
UBOOT_MACHINE = "u-boot-nodtb"